code/UserTag/capture_page.tag

   1 # Copyright 2003-2008 Interchange Development Group and others
   2 #
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2 of the License, or
   6 # (at your option) any later version.  See the LICENSE file for details.
   7 #
   8 # $Id: capture_page.tag,v 1.12 2008-10-01 09:21:45 racke Exp $
   9
  10 UserTag capture_page Order   page file
  11 UserTag capture_page addAttr
  12 UserTag capture_page Version $Revision: 1.12 $
  13 UserTag capture_page Routine <<EOR
  14 sub {
  15         my ($page, $file, $opt) = @_;
  16
  17         # check if we are using a file
  18         if ($file) {
  19                 # check if we are allowed to write the file
  20                 unless (Vend::File::allowed_file($file, 1)) {
  21                         Vend::File::log_file_violation($file, 'capture_page');
  22                         return 0;
  23                 }
  24
  25                 if ($opt->{expiry}) {
  26                         my $stat = (stat($file))[9];
  27
  28                         if ($stat > $opt->{expiry}) {
  29                                 if ($opt->{touch}) {
  30                                         my $now = time();
  31                                         unless (utime ($now, $now, $file)) {
  32                                                 ::logError ("Error on touching file $file: $!\n");
  33                                         }
  34                                 }
  35                                 return;
  36                         }
  37                 }
  38         }
  39
  40         if ($opt->{scan}) {
  41                 Vend::Page::do_scan($opt->{scan});
  42         }
  43
  44         $::Scratch->{mv_no_count} = 1;
  45
  46         # save mapped output
  47         my (@output, %outptr, %outfilter, %outextended, $multiout, $content, $retval);
  48
  49         @output = @Vend::Output;
  50         %outptr = %Vend::OutPtr;
  51         %outfilter = %Vend::OutFilter;
  52         %outextended = %Vend::OutExtended;
  53         $multiout = $Vend::MultiOutput;
  54
  55         # clear mapped output
  56         @Vend::Output = %Vend::OutPtr = %Vend::OutFilter = %Vend::OutExtended = ();
  57         $Vend::MultiOutput = 0;
  58
  59         Vend::Page::display_page($page, {return => 1});
  60
  61         for my $part (@Vend::Output) {
  62                 Vend::Interpolate::substitute_image($part);
  63                 $content .= $$part;
  64         }
  65
  66         # restore mapped output
  67         @Vend::Output = @output;
  68         %Vend::OutPtr = %outptr;
  69         %Vend::OutFilter = %outfilter;
  70         %Vend::OutExtended = %outextended;
  71         $Vend::MultiOutput = $multiout;
  72
  73         if ($opt->{scratch}) {
  74                 $::Scratch->{$opt->{scratch}} = $content;
  75                 $retval = 1;
  76         }
  77
  78         if ($file) {
  79            $retval = Vend::File::writefile (">$file", \$content,
  80            {auto_create_dir => $opt->{auto_create_dir},
  81                 umask => $opt->{umask}});
  82         }
  83
  84         return $retval;
  85 }
  86 EOR